» Kostenlose Alternative zu Boxcryptor/Viivo für Verschlüsselung in der Cloud?

• Entschlüsseln von verschlüsselten Dateien per Doppelklick (und Eingabe des Passworts)
• rechte Maustaste auf Dateien zum individuellen Verschlüsseln

@echo off
SETLOCAL EnableDelayedExpansion

REM BatchCryptor 2.0
REM (c) Gutt.IT 2017

REM #################################################
REM Settings:
REM #################################################
SET aes_source="C:\media\"
SET aes_target="C:\media_encrypted\"
SET aes_password="MyPassword"
REM #################################################
REM Optional:
SET aes_crypt="C:\Program Files\AESCrypt\aescrypt.exe"
REM #################################################

REM Step 1 - Encrypt files
FOR /R %aes_source% %%S IN (*.*) DO (
	%aes_crypt% -e -p %aes_password% "%%S"
)

REM Step 2 - Find encrypted files
SET aes_source_clean=!aes_source:"=!
SET aes_target_clean=!aes_target:"=!
FOR /R %aes_source% %%S IN (*.aes) DO (

REM Step 3 - Rename encrypted files
	SET /A count=1
	FOR /F "skip=1 delims=:" %%C IN ('CertUtil -hashfile "%%S" MD5') DO (
		IF !count! EQU 1 SET "md5_hash=%%C"
		SET /A count+=1
	)
	SET "md5_hash=!md5_hash: =!
	REN "%%S" !md5_hash!.aes

REM Step 4 - Move encrypted files to target folder
	SET source_filename=%%~dpS!md5_hash!.aes
	ECHO !source_filename!
	SET target_filename=!source_filename:%aes_source_clean%=%aes_target_clean%!
	ECHO !target_filename!
	FOR %%T IN ("!target_filename!") DO (
		SET target_path=%%~dpT
	)
	MD "!target_path!" 2> nul
	MOVE "!source_filename!" "!target_filename!"
)

• Quell-Verzeichnis (source)
• Ziel-Verzeichnis (target)
• und natürlich das Passwort

• man weiß nicht mehr welche Datei welche ist, da alle umbenannt wurden und bisher noch eine Log-Datei fehlt, wo man nachschauen könnte
• beim Entschlüsseln bleibt die Datei umbenannt. Auch hier könnte die Log-Datei helfen oder BatchCryptor erstellt von jeder Datei ein ZIP-Archiv, bevor er sie anschließend verschlüsselt.
• die Verzeichnis-Struktur wird 1:1 übernommen, könnte also evtl. was über den Inhalt verraten
• Um die Belegung von doppeltem Speicherplatz zu verhindern, könnte man direkt nach der Verschlüsselung die Originaldatei löschen d.h. man arbeitet grundsätzlich mit zwei Ordnern in der Bibliothek, wovon einer die Originaldateien enthält und der andere die verschlüsselten. Der Vorteil wäre dann, dass man genau diesen Ordner mit seinem bestehenden Cloud-Client von Dropbox, Amazon ^Anzeige. usw synchronisieren kann.
• das mit dem Ziel werde ich denke ich aufgreifen, weil man damit auch die Verzeichnisstruktur pro Datei speichern könnte wie z.B. "/videos/Kreta Urlaub 2015/movie.mp4"
• statt nur die Original-Dateien zu löschen könnte man symbolische Links auf die verschlüsselten Dateien stehen lassen um so das Nachschauen in einer Logdatei überflüssig zu machen

Mach mit!